(六)區(qū)域抓圖窗體
創(chuàng)建一個(gè)新的Form1，保存為Capture1.pas。設(shè)置屬性BorderIcons的四個(gè)屬性為false.
BorderStyle設(shè)為bsNone,Cursor設(shè)為crCross,FormStyle設(shè)為fsStayOnTop.
添加一個(gè)私有變量：fDragging:Boolean;兩個(gè)公共變量:fRect:TRect,fBmp:TBitmap;
Form1的作用：在區(qū)域抓圖時(shí)創(chuàng)建，抓圖后消失.

unit Capture1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm1 = class(TForm)
    PRocedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    fDragging:Boolean;
  public
    fRect:TRect;
    fBmp:TBitmap;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var aDC:HDC;  //設(shè)備描述表的句柄
begin
  fBmp := TBitmap.Create ;
  fBmp.Width := Screen.Width ;
  fBmp.Height:= Screen.Height;
  aDC := GetDC(0); //獲取一個(gè)窗口的設(shè)備描述表的句柄，0參數(shù)返回屏幕窗口設(shè)備描述表的句柄
  BitBlt(fBmp.Canvas.Handle,0,0,Screen.Width,Screen.Height,aDC,0,0,srcCopy);
  ReleaseDC(0,aDC,);
  SetBounds(0,0,Screen.Width,Screen.Height);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  fBmp.Free ;
end;

procedure TForm1.FormPaint(Sender: TObject);
begin
  Canvas.Draw(0,0,fBmp);  //將圖形繪制到 Canvas
end;

//如果按下鼠標(biāo)左鍵，用SetRect設(shè)置矩形fRect，使其只是一個(gè)點(diǎn)。
//用 DrawFocusRect 把這個(gè)矩形畫(huà)出來(lái)
procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if Button=mbLeft then begin
    fDragging:=true;
    SetRect(fRect,x,y,x,y);
    Canvas.DrawFocusRect(fRect);
  end;
end;

//鼠標(biāo)移動(dòng)時(shí), 判斷是否在畫(huà)圖中（按下鼠標(biāo)左鍵），DrawFocusRect重新設(shè)置矩形
//使右下角為當(dāng)前鼠標(biāo)位置，在調(diào)用DrawFocusRect畫(huà)出矩形
procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  if fDragging then begin
    Canvas.DrawFocusRect(fRect);
    fRect.Right := X ;
    fRect.Bottom:= Y ;
    Canvas.DrawFocusRect(fRect);
  end;
end;

//判斷是否在畫(huà)圖中（按下鼠標(biāo)左鍵），鼠標(biāo)彈起時(shí)，
//DrawFocusRect重新設(shè)置矩形  .關(guān)閉窗體
procedure TForm1.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if fDragging then begin
    Canvas.DrawFocusRect(fRect);
    fDragging:=false;
  end;
  ModalResult:=mrOK;   //關(guān)閉窗體
end;

end.