用vbscript合并多個(gè)文本文件的代碼

2020-03-24 18:21:57

字體：大中小

供稿：網(wǎng)友

問(wèn)：
嗨，Scripting Guy！在html' target='_blank'>命令提示符中，可以執(zhí)行命令“copy a.txt+b.txt ab.txt”來(lái)提取 a.txt 和 b.txt 的內(nèi)容，然后將它們合并到名為 ab.txt 的新文件中。可以使用腳本來(lái)實(shí)現(xiàn)相同的操作嗎？

-- DL

答：
嗨，DL。在昨天的專(zhuān)欄文章中，我們探討了有關(guān)文本文件的問(wèn)題；更具體地講，我們討論如何使用腳本來(lái)修改 .INI 文件。我們提到，這種解決方法盡管不是很巧妙，但可以達(dá)到目的。就今天的問(wèn)題來(lái)說(shuō)，同樣是這種情況。我們可以使用腳本來(lái)合并文本文件嗎？是的，可以。只不過(guò)有一點(diǎn)繁瑣，但效果很好。

我們所遇到的難題是，WSH 和 VBScript 都無(wú)法通過(guò)一條命令來(lái)合并文本文件，例如，objFile.AddTextFiles("file1.log","file2.log")。這有點(diǎn)讓人失望，但我們不會(huì)就此罷手，我們依然可以合并文本文件；只不過(guò)需要多執(zhí)行幾個(gè)步驟罷了。例如，要將 File1.log 和 File2.log 合并為一個(gè)文件（我們將其命名為 Output.txt），需要先讀取 File1.log，將該文件的內(nèi)容附加到 output.txt 末尾，然后讀取 File2.log，再將該文件的內(nèi)容附加到 Output.txt 末尾。事實(shí)上，我們必須使用類(lèi)似下面的腳本：

復(fù)制代碼代碼如下:
Const ForReading = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOutputFile = objFSO.CreateTextFile("output.txt")

Set objTextFile = objFSO.OpenTextFile("c:/logs/file1.log", ForReading)

strText = objTextFile.ReadAll
objTextFile.Close
objOutputFile.WriteLine strText

Set objTextFile = objFSO.OpenTextFile("c:/logs/file2.log ", ForReading)

strText = objTextFile.ReadAll
objTextFile.Close
objOutputFile.WriteLine strText

objOutputFile.Close

正如您所看到的一樣，該腳本并不是特別復(fù)雜。首先，我們定義一個(gè)常量 (ForReading)，用于打開(kāi)每個(gè)日志文件。接下來(lái)，創(chuàng)建一個(gè) FileSystemObject（用于處理文本文件的腳本技術(shù)）實(shí)例，并使用 CreateTextFile 方法創(chuàng)建一個(gè)名為 Output.txt 的新文件。

然后，打開(kāi)第一個(gè)文件 (C:/Logs/File1.log) 來(lái)讀取其中的內(nèi)容。我們使用 ReadAll 方法讀入整個(gè)文本文件，并將該信息存儲(chǔ)在變量 strText 中。然后，關(guān)閉 File1.log，并使用 WriteLine 方法將剛讀入的信息附加到新文件 Output.txt 的末尾。接下來(lái)，對(duì)下一個(gè)文件 (C:/Logs/File2.log) 執(zhí)行相同的過(guò)程。讀入第二個(gè)文件后，Output.txt 將包含第一個(gè)文件以及第二個(gè)文件中的所有信息。哈哈，我們成功了！

我們知道您在想什么：不錯(cuò)，盡管上述腳本可以實(shí)現(xiàn)目的，但問(wèn)題是您必須“事先”知道文件夾 C:/Logs 中所有文件的名稱(chēng)。那么，編寫(xiě)一個(gè)腳本以獲取 C:/Logs 中的所有文件并將它們合并在一起，豈不是更好？嗯，我們還未曾這樣想過(guò)。您所說(shuō)的是不是類(lèi)似下面的腳本：

Const ForReading = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOutputFile = objFSO.CreateTextFile("output.txt")

strComputer = "."
Set objWMIService = GetObject("winmgmts://" & strComputer & "/root/cimv2")

Set FileList = objWMIService.ExecQuery _
("ASSOCIATORS OF {Win32_Directory.Name='C:/Logs'} Where " _
& "ResultClass = CIM_DataFile")

For Each objFile In FileList
Set objTextFile = objFSO.OpenTextFile(objFile.Name, ForReading)
strText = objTextFile.ReadAll
objTextFile.Close
objOutputFile.WriteLine strText
Next

objOutputFile.Close

實(shí)際上，我們?cè)诖颂巿?zhí)行的全部操作是獲取 C:/Logs 文件夾中所有文件的集合；這是通過(guò)以下 WMI Associators of 查詢(xún)實(shí)現(xiàn)的：

Set FileList = objWMIService.ExecQuery _
("ASSOCIATORS OF {Win32_Directory.Name='C:/Logs'} Where " _
& "ResultClass = CIM_DataFile")

在獲取這一集合后，我們可以立即使用 For-Each 循環(huán)打開(kāi)每個(gè)文件并讀入其中的文本（使用 ReadAll 方法，與上文中的代碼相同）。然后關(guān)閉該文件，將文本附加到輸出文件的末尾。接下來(lái)再執(zhí)行一次循環(huán)，對(duì)集合中的下一個(gè)文件執(zhí)行相同的過(guò)程。只需片刻，就可以將 C:/Logs 中所有文件的所有文本提取出來(lái)，并將它們合并為一個(gè)名為 output.txt 的新文件。整個(gè)過(guò)程就是這么簡(jiǎn)單。
html教程

鄭重聲明：本文版權(quán)歸原作者所有，轉(zhuǎn)載文章僅為傳播更多信息之目的，如作者信息標(biāo)記有誤，請(qǐng)第一時(shí)間聯(lián)系我們修改或刪除，多謝。

上一篇：VBScript教程第十三課 VBScript與窗體

下一篇：CreateWeb.vbs 代碼