var a:Object = new Object();
var b:Object = a; // b和a引用同一個new Object();
delete a;
trace(b); // 輸出[object Object] - 在內存中還是存在
delete b;
// GC將回收object
這個特性在Flash8和9（AS123）中幾乎都是一樣的，但是在Flash8中，GC的一些特性得到改善并能更好的工作。（注意，垃圾收集不是即時的）
雖然GC在AS3中并沒有什么本質上的改變，但是因為使用了新的虛擬機，delete關鍵字的行為有所改變。現在，delete關鍵字只能針對類的動態屬性和非公有成員有效。而在AS1和2中，delete能被用在所有的東西上。

// ActionScript 2
class DeleteVarClass {
public var myVar:Number;
function DeleteVarClass() {
myVar = 1;
trace(myVar); // 1
delete myVar;
trace(myVar); // undefined
}
}
// ActionScript 3
package {
public class DeleteVarClass {
public var myVar:Number;
public function DeleteVarClass() {
myVar = 1;
trace(myVar); // 1
delete myVar;
trace(myVar); // 1
}
}
}
在上面的AS3例子中，因為myVar變量是一個公有成員，所以不能用delete來刪除這個變量。
盡管在AS3中不能刪除類成員，但是如果你想刪除一個對象的所有引用，可以通過將變量設置為null來代替delete。如：

myVar = null;
如果一個對象的所有引用都是null，GC將自動的從內存中刪除這個對象。
11，Dictionary類
AS3中的Dictionary類（flash.utils.Dictionary）是一個新的AS類。Dictionary類和Object唯一的區別在于：Dictionary對象可以使用非字符串作為鍵值對的鍵。例如：

var obj:Object = new Object();
obj["name"] = 1; // 鍵是字符串"name"
obj[1] = 2; // 鍵是1 (被轉換成字符串"1")
obj[new Object()] = 3; // 鍵是new Object()，被轉傳成字符串"[object Object]"
for (var prop:String in obj) {
trace(prop); // 輸出：[object Object], 1, name
trace(obj[prop]); // 輸出：3, 2, 1
}
也就是說，無論用什么類型的變量作為鍵，都將被轉換成字符串。同時，如果你使用了不同的對象作為鍵，都會北轉換成字符串"[object Object]"作為鍵，因此而指向了同一個數據。例如：

ActionScript Code:
var a:Object = new Object();
var b:Object = new Object();
var obj:Object = new Object();
obj[a] = 1; // obj["[object Object]"] = 1;
obj[b] = 2; // obj["[object Object]"] = 2;
for (var prop:String in obj) {
trace(prop); // traces: [object Object]
trace(obj[prop]); // traces: 2
}
Dictionary類將沒有這個限制，你可以將鍵設置成任何一種數據類型。例如：

import flash.utils.Dictionary;
var a:Object = new Object();
var b:Object = new Object();
var dict:Dictionary = new Dictionary();
dict[a] = 1; // dict[a] = 1;
dict[b] = 2; // dict[b] = 2;
for (var prop:* in dict) {
trace(prop); // traces: [object Object], [object Object]
trace(dict[prop]); // traces: 1, 2
}
雖然在trace的時候，輸出的還是[object Object]，但是這個結果是對象的toString的結果。在Dictionary對象中，代表的是不同的對象引用。
注意，這里的prop的類型是*。這是很重要的，因為dict對象中的鍵可能是任何數據類型的。