bat、vbs、js 原生混編(一個bat可以執行vbs，js代碼)

2020-07-26 20:12:18

字體：大中小

來源：轉載

供稿：網友

發現 mshta 會把 file:// 協議指向的文件當作 html 來解析（注：IUnknown 與 happyxxdhaha 提醒此處必需使用絕對路徑，否則不會執行），心里頓時有一萬只草泥馬奔過，原來如此簡單的答案就在身邊，卻錯過了四年

基本框架：

復制代碼代碼如下:

<!-- : bathome
@echo off
echo I'm Batch!
mshta "file://%~f0"
pause&exit
使用注釋標簽囊括批處理部分，條件是批處理部分不能出現注釋標簽的結束符
-->
<script language=vbs>
Msgbox "I'm VBScript!"
</script>
<script>
alert("I'm JavaScript!")
</script>
<script>close()</script>

事實上，file:// 協議名可以省略，而且如果不需要理會界面的話，完全可以不用注釋標簽：

復制代碼代碼如下:

@echo off
echo I'm Batch!
mshta "%~f0" <nul
pause&exit
批處理部分之后要加上一串 >，數量要比前文出現的 < 更多，mshta 才能區分哪些是標簽
而且前文出現從文件獲取重定向輸入的時候，建議加上雙引號，例如 <"script"
>>>>>>>>>>>>>>
<script language=vbs>
Msgbox "I'm VBScript!"
</script>
<script>
alert("I'm JavaScript!")
</script>
<script>close()</script>

另一用 goto 的種寫法可能更直觀一點：

復制代碼代碼如下:

@goto :bat
<script language=vbs>
Msgbox "I'm VBScript!"
</script>
<script>
alert("I'm JavaScript!")
</script>
<script>close()</script>
:bat
@echo off
echo I'm Batch!
mshta "%~f0" <nul
pause&exit

要注意的是，這里的宿主是 mshta，所以不支持 WSH 宿主的方法和屬性（部分屬性或方法的替代方案詳見后文）
但是！mshta 有嘛不好！
原生支持 setTimeout
原生支持 iframe
原生支持 dom
原生支持 javascript、vbscript 無障礙交互
原生支持 Ajax
原生支持加載外部腳本
原生支持在窗口中選擇文件
原生支持復雜的頁面交互
...
有這么多便利，那還計較什么呢？
首發于批處理之家
------------------------------------------------------------------------------------------------------------
關于 mshta 宿主的一些知識，參考： https://msdn.microsoft.com/en-us/library/ms536495(VS.85).aspx
感謝 xiaopo 掃盲，才知道聯盟早已出現過 mshta 方案的雛形：http://cndos.fam.cx/forum/viewthread.php?tid=39655，回頭上鏡像站搜下，看看有沒有進一步的發展

復制代碼代碼如下:

:<!--
::::::::::::::::::::::::::::::::BAT::::::::::::::::::::::::::::::::

::::::::1.執行HTML代碼之前的BAT代碼::::::::
@echo off
call :e Starting mshta...
pause
::::::::1.執行HTML代碼之前的BAT代碼::::::::

::執行HTML代碼：
start mshta %0

::::::::2.執行HTML代碼之后的BAT代碼::::::::
call :e Mshta is executing HTML codes...
pause
::::::::2.執行HTML代碼之后的BAT代碼::::::::

::退出BAT：
exit/b

:::::::BAT函數定義部分:::::::
:e
echo %*
goto :eof
:::::::BAT函數定義部分:::::::

::::::::::::::::::::::::::::::::BAT::::::::::::::::::::::::::::::::
-->

<script>document.body.innerText=""</script>

<body onkeypress=window.close()>
<hr color=red>
<marquee><font color=green>HTML Codes</font></marquee>
<hr color=red>

上一篇：Windows命令行bat批處理延遲sleep方法(批處理延時)

下一篇：批處理添加多個新的域名到hosts