超級SWF跟蹤器－巧用LocalConnection的代碼
2024-09-12 17:50:44
供稿：網友
FLASH中的trace只能在FLASH IDE中跟蹤看到，如果你將SWF發(fā)布到網上，是看不到trace的調試信息，這給開發(fā)網絡FLASH帶來的調試上的困難，那有沒有好的辦法來解決這個問題呢，不管SWF發(fā)布到什么地方，打開一個本地SWF跟蹤器來接收調試消息那豈不是很好，因為我嘗試了各種方法，從SharedObject的本地對象到遠程對象到LocalConnection的方法都嘗試一遍（使用LocalConnection是從Breeze AddIn中發(fā)現(xiàn)的一個“秘密”，感覺SNOW給我了一個提示，發(fā)現(xiàn)了其中的“奧秘”），在需要調試的SWF中使用下面的類：
class fj.util.JTracer {
public static var debug:Boolean=true;
private static var _instance:JTracer;
private var _lc:LocalConnection;
private function JTracer(){
this._lc=new LocalConnection();
this._lc.allowDomain=function(domain:String):Boolean{
return true;
}
}
public static function trace(msg:Object):Void{
if(!JTracer.debug){
return;
}
if(JTracer._instance==undefined){
JTracer._instance=new JTracer();
}
JTracer._instance.traceMsg(msg);
}
private function traceMsg(msg:Object):Void{
trace(msg);
this._lc.send("localhost:trace","trace",this._lc.domain(),msg);
}
}
使用方法很簡單，就是JTracer.trace("我來試試!");
SWF跟蹤器中的代碼如下：
import fj.util.JDelegate;
class view.JDebug {
private var _ui:MovieClip;
private var _lc:LocalConnection;
function JDebug(ui){
this._ui=ui;
this.init();
}
private function init(){
this._lc=new LocalConnection();
this._lc.allowDomain=function(domain):Boolean{
return true;
}
this._lc.connect("trace");
this._lc.trace=JDelegate.create(this,onTrace);
}
private function onTrace(domain:String,msg:Object){
this._ui.msg_ta.text+=domain+":"+msg+"/n";
}
}
這個需要放一個組件TextArea名字叫msg_ta,用來顯示跟蹤的消息！
